高级结构 | 邱维东

在本章中，我们将研究各种非常有用且使用越来越广泛的非 OOP 结构。

λ函数

lambda 函数是一个匿名函数，它可以自由引用包含它的函数中的局部变量(包括参数变量)。除了编译器负责为 lambda 函数生成内部名称以外，Lambda 的实现与 Pascal 的嵌套函数一样。有几种不同的方法可以实现 lambda 函数(更多相关信息，请参阅 Wikipedia on Nested Functions)。

int foo(int a)
{
  auto function = [a](int x) { return x + a; };
  return function(10);
}

这里的问题是 lambda 函数引用了调用者的一个局部变量 a。这可以通过将局部变量作为隐式参数传递给 lambda 函数来轻松解决：

define internal i32 @lambda(i32 %a, i32 %x) {
	%1 = add i32 %a, %x
	ret i32 %1
}

define i32 @foo(i32 %a) {
	%1 = call i32 @lambda(i32 %a, i32 10)
	ret i32 %1
}

或者，如果 lambda 函数使用多个变量，您可以将它们包装在一个结构中，然后将该结构体的指针传递给 lambda 函数：

extern int integer_parse();

int foo(int a, int b)
{
  int c = integer_parse();
  auto function = [a, b, c](int x) { return (a + b - c) * x; };
  return function(10);
}

转换为llvm：

; ModuleID = 'lambda_func_1_cleaned.ll'
source_filename = "lambda_func_1_cleaned.ll"
target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
target triple = "x86_64-unknown-linux-gnu"

%lambda_args = type { i32, i32, i32 }

declare i32 @integer_parse()

define i32 @lambda(%lambda_args* %args, i32 %x) {
  %1 = getelementptr %lambda_args, %lambda_args* %args, i32 0, i32 0
  %a = load i32, i32* %1
  %2 = getelementptr %lambda_args, %lambda_args* %args, i32 0, i32 1
  %b = load i32, i32* %2
  %3 = getelementptr %lambda_args, %lambda_args* %args, i32 0, i32 2
  %c = load i32, i32* %3
  %4 = add i32 %a, %b
  %5 = sub i32 %4, %c
  %6 = mul i32 %5, %x
  ret i32 %6
}

define i32 @foo(i32 %a, i32 %b) {
  %args = alloca %lambda_args
  %1 = getelementptr %lambda_args, %lambda_args* %args, i32 0, i32 0
  store i32 %a, i32* %1
  %2 = getelementptr %lambda_args, %lambda_args* %args, i32 0, i32 1
  store i32 %b, i32* %2
  %c = call i32 @integer_parse()
  %3 = getelementptr %lambda_args, %lambda_args* %args, i32 0, i32 2
  store i32 %c, i32* %3
  %4 = call i32 @lambda(%lambda_args* %args, i32 10)
  ret i32 %4
}